Importar Retenciones de IVA al SIAP

El título completo sería "Importar Retenciones de IVA al SIAP desde una planilla de Excel". En fin... Bueno, hagamos una linda introducción para luego ir metiéndonos en tema, un tema que sirve directamente a los contadores, estudios contables y personas que se liquiden sus impuestos.

Si te aburre o no tenés ganas de leer todo, abajo está la planilla terminada.

Yo se que alguien me va a decir "Las retenciones de IVA se bajan directamente de la página de la AFIP y se importan". Y tienen razón! Pero esta explicación (si la entienden) puede servir para 3 cosas:

1) Para la que más me gusta a mi convencerte: ejercitar la materia gris! Pensar ayuda a tomar buenas decisiones, acompáñenme hasta el final, no se salteen todo para bajar la planilla! El que abandona, no tiene premio.



2) Les puede servir para otros aplicativos. Pero como dije antes de puntualizar este apartado, es requisito ENTENDERLO. Luego de entenderlo, van al apartado de "Importación" de cualquier aplicativo (incluso no solo de AFIP, sino de RENTAS o cualquier soft que permita importación de datos a partir de archivos txt), estudian el formato y se ahorran unas cuántas horas. Y en dichas horas, mientras toman una cervecita, pueden pensar "No era solo para Nerds este asunto de la materia gris, eh?"

3) Para experimentar eso de "programar". Si entendiste los condicionales de la entrada de "Prode para amigos" y entendés el manejo de cadenas y otras yerbas que vamos a ver acá y te gusta, ni lo dudes: leete lo que puedas por internet, hacete un cursito y explorá este facinante mundo!

Me fui por las ramas! Introducción dijimos.

Las retenciones QUE NOS HACEN, son importes retenidos por un cliente, que se toman como pagos a cuenta de algún impuesto y que se van haciendo a lo largo de un período (generalmente son eso).

RETENCIONES DE IVA: Si un buen hombre nos tiene que pagar 100 y es agente de retención de IVA, nos pagará 80 y nos dará un papelito, diciendo que nos retuvo 20. Esos 20 son los pagos adelantados que nos tomaremos en el IVA. El período es mensual. Esto quiere decir, que al cargar la Declaración Jurada de IVA y al cargar todas las yerbas que eso conlleva, vamos a tener que cargar uno por uno estos papelitos (certificados de retención) que nos han venido haciendo a lo largo del mes que finalizó para que el sistema los "reste" del importe a pagar (y si no diera a pagar, quedará para períodos posteriores).

Ok. Supongamos que tenemos una persona encargada de los pagos, que va contabilizando en una planilla todas las retenciones que nos fueron haciendo.

Llega el momento de liquidar el IVA, y el liquidador imprime esa planilla (o lo que es peor, ni sabe de la existencia de esa planilla y agarra los comprobantes!) y se pone a cargarlos en el aplicativo. ERROR.

Comenzamos con la acción:


PASO 1: Estudiamos el formato.

No voy a explicar como instalar y/o usar el aplicativo SIAP ni el de IVA, no es objetivo ni del blog ni de la entrada. Lo que si les voy a decir, son los pasos para llegar a la importación.
Entramos en la parte donde se cargan las retenciones y hay un botoncito con una hojita y 3 disquetes. Si pasamos el mouse sobre este botón, dice "Importar". Vamos a ver una pantalla como la que sigue:

        Hacer click sobre la imágen para ampliarla

Nos vamos a centrar en lo que dice este cuadro. Para llegar al preciado archivo que nos pide en el botón "Seleccionar archivo de origen para la imputación", vamos a tener que respetar los "renglones" del archivo txt, sabiendo que cada renglón será un registro (una retención).

Vamos a aprovechar la ayuda del aplicativo (arriba, en "Ayuda", "Acerca De..."). Allí, hay un apartado que se llama "Importar". en el mismo, podrán encontrar los Códigos de Régimen de Retenciones y Percepciones. 

Ahora, a traducir:
Campo 1: Código de Régimen de Retención: No tiene mayor complicación. Ocupa los primeros 3 lugares del renglón, se consulta en la ayuda (va a estar en la planilla que deje al final) y yo en el ejemplo, voy a usar uno de los más comunes: 214 Compraventa de cosas muebles y locaciones
Campo 2: CUIT: Voy a usar el formato tradicional: 00-00000000-00. Si leen en la ayuda, verán 2 formatos más: con espacios en lugar de "-", y con 2 espacios adelante y el CUIT seguido sin separación. En todos los casos, tiene que ocupar 13 posiciones.
Campo 3: Fecha: también uso el formato tradiciona dd/mm/aaaa (en la Ayuda, dice que también podemos usar dd-mm-aaaa. Es decir, lo mismo pero con "-")
Campo 4: En la Ayuda dice que tiene formato numérico y ocupa 16 posiciones. Todos los lugares a la izquierda que falten serán ocupados por espacios.
Campo 5: Acá, PRESTAR ATENCION al separador decimal de Windows (en la ayuda lo explica bien). Pero no se desesperen: el separador decimal de windows, coincide con el de Excel. Así que no debería haber problemas. El resto, con posiciones en blanco hacia la izquierda.

Bueno, voy a usar los * como espacios (en la planilla van a ser espacios, es solo para que lo vean). Ya efectuada esta aclaración, cada registro deberá quedar masomenos así:

21400-00000000-031/12/2012************1234***********12,00

donde la retención es código 214, el CUIT es 00-00000000-0, la fecha es 31/12/2012, el certificado es el 1234, el valor de la retención es de $ 12 y... lo aclaro nuevamente... LOS ASTERISCOS SON ESPACIOS! Por si no quedó claro! jaja


PASO 2: Dando formato a los campos

Supongamos que tenemos la siguiente planilla:

       Hacer click sobre la imágen para ampliarla

Pueden tener más columnas (razón social, monto facturado, IVA, etc), pero las puestas en este ejemplo son las mínimas necesarias.

Lo que vamos a hacer es analizar campo por campo.

Recomiendo leer las entradas anteriores a esta, que son las funciones que podamos necesitar (si es que no tienen manejo de las mismas). Les dejo los enlaces como referencia:

Funcion TEXTO
Funciones SUSTITUIR y CONCATENAR
Funciones LARGO, REPETIR Y ESPACIOS
Funciones IZQUIERDA, DERECHA y EXTRAER

Ahora si, vamos por campos:

CAMPO 1

En la celda H4, le damos formato de texto a B4 como "000", por si tiene un código de 2 dígitos, con la función TEXTO. Esta columna debería tener como máximo 3 dígitos. Y esto debería ser regla, porque podemos usar "IZQUIERDA", pero estaríamos cortando algo que tiene que ser exacto. Poniendo cualquier regimen (arbitrario), corremos el riesgo de cargar la retención en CUALQUIER LADO, o que nos tire error a la hora de importar.
Retomando, en H4 ponemos =TEXTO(B4;"000")

Dejo la imagen:

       Hacer click sobre la imágen para ampliarla

Como hemos visto en ocasiones anteriores, nos situamos con el mouse en el extremo inferior derecho de la celda H4 hasta que el cursor se transforme en una cruz oscura, y deslizamos hacia abajo para que pegue la fórmula en las celdas correspondientes. Aclaro que, además de los formatos de los bordes y el sombreado al encabezado, centralicé todos los datos.

CAMPO 2:

Ahora nos ocupamos del CUIT. En mi planilla no tengo los "-" separadores, pero la fórmula que vamos a aplicar, sirve tanto si la tuviéramos como si no.
Nos situamos en I4 y escribimos: =TEXTO(C4;"00-00000000-0")

La imagen para que vean como va quedando:

       Hacer click sobre la imágen para ampliarla

CAMPO 3:

Llega el turno de la fecha, lo que no debería ocasionarnos inconvenientes, puesto que con "TEXTO" le damos el formato. Muchos pensarán "Para que hacer este paso previo, y no concatenar todo directamente?" Justamente "Fecha" es uno de los tantos datos que se ven distorsionados a la hora de concatenar sin poner previamente un formato: nos tomaría un número "horrible". Pruébenlo.
Entonces, en J4 ponemos =TEXTO(D4;"dd/mm/yyyy")

La imagen:

        Hacer click sobre la imágen para ampliarla

CAMPO 4:

El tema del Certificado, lo vamos a dividir en 2 para que no sea larga la fórmula y se pueda entender mejor. Recordemos que se deben llenar con espacios a la izquierda del número, para llegar a los 16 dígitos requeridos.

Paso 1: Cortamos el certificado en 16, y sacamos los espacios (en caso que los tenga, los saca). Para eso, en K4 ponemos: =IZQUIERDA(ESPACIOS(E4);16)

Ver las entradas anteriores (y citadas en esta entrada) para entender. Pero básicamente, lo que hace es PRIMERO sacar los espacios de E4 (si existiesen) mediante la funcion ESPACIOS (E4). A lo que queda de eso se toman los primeros 16 caracteres IZQUIERDA (Resultado anterior;16). 

Lo pinto de celeste para recordar que esto lo uso de puente, y que NO se va a concatenar con nada. Dejo la imagen:

       Hacer click sobre la imágen para ampliarla

Paso 2: En la columna de al lado, hacemos lo que falta: tomar el valor que acabamos de obtener, y añadirle los espacios faltantes. La fórmula es la siguiente: =REPETIR(" ";16-LARGO(K4))&K4

También hay un buen ejemplo en las entradas anteriores de las funciones REPETIR y LARGO, acerca de este tema. Lo que hace es repetir 16 - largo de K4, espacios. Al final, se anexa K4 y con eso se obtienen los 16 caracteres necesarios.

La imagen:

       Hacer click sobre la imágen para ampliarla

CAMPO 5:

Vamos a dividirlo en 2 pasos, como hicimos con el Campo anterior.

Paso 1: En M4 ponemos: =TEXTO(F4;"0,00"). Con esto, le damos el formato de TEXTO (cadena de texto y no número) y ponemos los 2 decimales. Para ver la utilización de los 0, recomiendo ver la entrada anterior a esta que habla de la función TEXTO.

También lo pinto de celeste para recordar que esto lo uso de puente, y que NO se va a concatenar con nada. La imagen:

        Hacer click sobre la imágen para ampliarla

Paso 2: En la columna de al lado, hacemos lo que falta: tomar el valor que acabamos de obtener, y añadirle los espacios faltantes delante. La fórmula es la siguiente: =REPETIR(" ";16-LARGO(M4))&M4

Como en el anterior campo he señalado, hay un buen ejemplo en las entradas anteriores de las funciones REPETIR y LARGO, acerca de este tema. Lo que hace es repetir 16 - largo de M4, espacios. Al final, se anexa M4 y con eso se obtienen los 16 caracteres necesarios.

La imagen:

        Hacer click sobre la imágen para ampliarla

PASO 3: Finalizando el archivo e importando

Listo! Tenemos todos nuestros datos con el formato correcto. Solo queda concatenarlos (no voy a usar la función CONCATENAR, voy a usar los signos &, pero se puede hacer con la función). En O4, quedaría la siguiente fórmula (recordemos que los campos en celeste son puente y no forman parte):
=H4&I4&J4&L4&N4

La imagen:

       Hacer click sobre la imágen para ampliarla

Por último, COPIAMOS los valores del primer al último registro, seleccionando en nuestro ejemplo el rango O4:O19, click derecho, COPIAR:

        Hacer click sobre la imágen para ampliarla

Creamos un nuevo documento de texto en la carpeta que querramos y que luego recordemos para seleccionar el archivo dentro del SIAP, de la siguiente manera: click derecho>Nuevo>Archivo de texto (o inicio>programas>accesorios>bloc de notas) y lo guardamos con el nombre que deseemos (por ejemplo "Retenciones Ganancias.txt"). Abrimos ese documento y pegamos lo que teníamos copiado. Quedaría algo así:

       Hacer click sobre la imágen para ampliarla

Lo cerramos, al preguntar si guardamos obviamente le damos a Aceptar. Volvemos al SIAP, al botón "Importar" dentro de la solapa de "Retenciones". Les refresco la imagen:

Damos al botón "Seleccionar archivo de origen para la imputación":

        Hacer click sobre la imágen para ampliarla

Y si todo está ok, nos tendría que dar este mensaje de la buena suerte:

        Hacer click sobre la imágen para ampliarla

Podemos corroborar que se hayan cargado las retenciones de forma correcta! Para eso, vamos cerrando ventanas hasta quedar en las retenciones. Nos desplazamos por los renglones hasta encontrar nuestro regimen, y verificamos:

       Hacer click sobre la imágen para ampliarla

Asunto terminado!

******************************

CONSIDERACIONES FINALES

Una vez terminada (o descargada) la planilla, se puede copiar y pegar las fórmulas que fuimos haciendo, o bien copiar y pegar los datos (CUIT, Nro de certificado, etc) en la misma planilla. Es indistinto. De lo que estoy seguro, es que una vez conocida la planilla y su funcionamiento, se pueden cargar 10 o 1000 retenciones en menos de 5 minutos.

En el archivo que voy a adjuntar, tiene una hoja de cálculo con todos los regimenes (que, vuelvo a repetir, también los pueden encontrar en la Ayuda del aplicativo de IVA).

Si necesitan alguna planilla en especial, me lo comentan en los comentarios y veo como los puedo ayudar. Si no es demasiado complicada no tengo problemas en hacerla. Pero sería interesante que lo hagan ustedes y sentir que todo este tiempo empleado no fue en vano.

¿Se puede hacer todo esto junto? Si, claro! Les dejo la fórmula completa:

=TEXTO(B4;"000")&TEXTO(C4;"00-00000000-0")&TEXTO(D4;"dd/mm/yyyy")&REPETIR(" ";16-LARGO(IZQUIERDA(ESPACIOS(E4);16)))&IZQUIERDA(ESPACIOS(E4);16)&REPETIR(" ";16-LARGO(TEXTO(F4;"0,00")))&TEXTO(F4;"0,00")

No es dificil de entender, el tema es que se presta al error y si hay que modificar algo, MAMITA! Y ni te cuento si a la AFIP se le ocurre cambiar el formato o meterle algún dato más. Lo mejor y más ordenado, es hacer las cosas por partes. Cuánto más chiquita sea la parte, más fácil será entenderla y corregir posibles errores.

******************************

FIN DEL TUTORIAL

Como digo en estos casos, si llegaste hasta el final, tengo que agradecerte por hacer el esfuerzo. El que abandona, no tiene premio.

DESCARGA: Para descargar la planilla (son iguales, dejo 2 servidores por si se cae alguno, la contraseña es exceldiario)

                                               Fileserve

Mediafire

Hacé clic para ver de que forma podés colaborar con nosotros:

Hasta la próxima!